Meattwad's Simple Beggar

[Meatt Wad]

With some help from E.N. I think my first script is ready to be submitted and tested by more folks.
I have tested to GM 50-GM in about 38 hours. (Using no tricks)
This is primarily for people who can not use C2's, don't have an attendant or if it gets nerfed. 
I ran this script from 88 to gm in 1 solid run with 0 hiccups.

Code: [Select]

;==================================
; Script Name:  Meatt Wad's Simple Beggar
; Author: Meatt Wad
; Version: 1.0
; Client Tested with: 7.0.18
; EUO version tested with: 1.5.202
; Shard OSI: OSI
; Revision Date: Oct 6, 2011
; Public Release:
; Purpose: Automate Begging
; Globals: none
;====================================
;
;====================================
; Instructions: Find a heavily populated area of NPC's or better yet . . .
; Go Hire Blue NPC's, fighters, beggar's whatever(15 to 20 should do), has to be the ones you pay to follow you.
; Take them to your house and trap them (I like walking them up to third floor and leaving a hole to 2nd
; Allow them to fall through to 2nd floor with no doors and no teles no stairs so they can't escape.)
; I also like to make this room fairly small like 8x8 or less so they are within begging range.
;====================================
; Thanks to everyone at SUO for all the help!
;====================================
; Special thanks to Endless Night for sharing your knowledge with me and helping to edit this script!
;====================================

set %ver 1.0

chooseskill BEGG   
set %skill #skill
set %BEGG #skill
set %gain 0
set %gains 0
set %status Begging
menu show 290 112
menu hideEUO
gosub menu

;======== Main Loop ================

REPEAT
  gosub find
  gosub beg
  gosub skillgain
  gosub UpdateMenu
until #charghost = yes  || #Skill = #Skillcap
halt

;======== Update Menu Sub ===========

sub UpdateMenu
  str len %gains
  str ins %gains #dot #strRes
  menu set EUOLabel4 #strRes
  str len #skill
  str ins #skill #dot #strRes
  menu set EUOLabel6  #strRes   
  menu set EUOLabel3 %status

  if #Charghost = yes
    display You are Dead! Script Halted!
return

;============= Find Sub ==========

sub find
  repeat
    wait 1
    finditem HS_IS G_10       
    if #findcnt = 0
        ignoreitem reset
    if #findid = #charid
        ignoreitem #FINDID
  until #FINDcnt >= 1 && #findid <> #charid 
RETURN 

;============ Beg Sub ===============

sub beg
  move #FINDX #FINDY 1 10s
  ignoreitem #FINDID   
  if #FINDDIST > 1
    return
  Repeat   
    chooseskill BEGG
    set %skill #SKILL
    set #LTARGETID #FINDID
    set #LTARGETKIND 1
    event macro 13 6
    target
    event macro 22
    wait 10s
return

;=============Skillgain sub============

sub skillgain
  chooseskill BEGG
  if #skill > %BEGG
    set %gains %gains + #skill - %BEGG
  set %BEGG #skill

  if #skill = #skillcap
     {
    display You have reached your skill cap.$
            +$Thanx for using Meatt Wad's Simple Begger
            +$
            +$Please rate the script at ScriptUO.com
            +$
            +$
            +Script is Halted$
            +$
            + ~ Meatt Wad$
     }
return

;=========== EasyUO Menu Designer Code ============

sub menu
  menu Clear 
  menu Window Title MeattWads Simple Beggar %ver
  menu Window Color Black
  menu Window Size 290 112
  menu Font Transparent #true
  menu Font Align Right
  menu Font Name MS Sans Serif
  menu Font Size 14
  menu Font Style
  menu Font Color $9933CC
  menu Font Transparent #false
  menu Font Align Left
  menu Font BGColor Black
  menu Text EUOLabel1 10 40 Gains:
  menu Text EUOLabel2 10 72 Status:
  menu Font Size 8
  menu Text EUOLabel3 70 80 %status
  str len %gains
  str ins %gains #dot #strRes
  menu Text EUOLabel4 70 48 #strRes
  menu Font Size 14
  menu Text EUOLabel5 22 10 Skill:
  menu Font Size 8
  str len #skill
  str ins #skill #dot #strRes
  menu Text EUOLabel6 70 18 #strRes
return

;====================================================

This script will train anywhere from 0-100 in Begging. ( Get those Trick or Treat Rewards for Halloween .)

Instructions are in the script.  Main thing is to gather blue hireable npcs, take them to your house and trap them and dismiss.
     The more the better, I used 15-30 more should be even better.

This script waits the full 10 seconds required by UO, mostly so it will work even if whatever wait trick you like gets nerfed.

Give it a shot and let me know what you think.

[onlyindreams]

Three years later and this still runs just fine! It's just a shame that there isn't a way to bypass the skill wait timer.

Hopefully I can get trained to GM by Tuesday.

[Crisis]

This is still working good, wish I had the personal attendant so I could try C2's though lol.

[The Ghost]

there a few for sale , Atl have 1 and Pac have 4.  Which shard are you playing. 

[Crisis]

Chessy

[The Ghost]

Don't have a transfer for this shard.  Now I need a suit I know how to contact

[Crisis]

Don't have a transfer for this shard.  Now I need a suit I know how to contact

I can make you a LRC suit and help you get set up if you ever want to visit.

[Endless Night]

Congratulations your Script has been moved to the script library
(if you dont think the section is appropriate please pm me)
Thank you for your submission

[Triunn]

Might be weird reviving this post BUT I really just wanted to say that this still works in 2020!

[Crisis]

Not weird at all, good to let others know it still works if it has been a while since anyone posted!

[baldielocks]

Thanks for the script. Works well. I added in ignore #findrep 2-7 because of all the invulnerable npc's now.

Code: [Select]

    if #findrep = 2_3_4_5_6_7
       ignoreitem #FINDID